Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

Tools

perlpragma

Perl 5 version 10.1 documentation
Go to top
Show page index • Show recent pages
Recently read

perlpragma

NAME

perlpragma - how to write a user pragma

DESCRIPTION

A pragma is a module which influences some aspect of the compile time or run time behaviour of Perl, such as strict or warnings . With Perl 5.10 you are no longer limited to the built in pragmata; you can now create user pragmata that modify the behaviour of user functions within a lexical scope.

A basic example

For example, say you need to create a class implementing overloaded mathematical operators, and would like to provide your own pragma that functions much like use integer; You'd like this code

  1.     use MyMaths;
  2.     
  3.     my $l = MyMaths->new(1.2);
  4.     my $r = MyMaths->new(3.4);
  5.     
  6.     print "A: ", $l + $r, "\n";
  7.     
  8.     use myint;
  9.     print "B: ", $l + $r, "\n";
  10.     
  11.     {
  12.         no myint;
  13.         print "C: ", $l + $r, "\n";
  14.     }
  15.     
  16.     print "D: ", $l + $r, "\n";
  17.     
  18.     no myint;
  19.     print "E: ", $l + $r, "\n";

to give the output

  1.     A: 4.6
  2.     B: 4
  3.     C: 4.6
  4.     D: 4
  5.     E: 4.6

i.e., where use myint; is in effect, addition operations are forced to integer, whereas by default they are not, with the default behaviour being restored via no myint;

The minimal implementation of the package MyMaths would be something like this:

  1.     package MyMaths;
  2.     use warnings;
  3.     use strict;
  4.     use myint();
  5.     use overload '+' => sub {
  6.         my ($l, $r) = @_;
  7. 	# Pass 1 to check up one call level from here
  8.         if (myint::in_effect(1)) {
  9.             int($$l) + int($$r);
  10.         } else {
  11.             $$l + $$r;
  12.         }
  13.     };
  14.     
  15.     sub new {
  16.         my ($class, $value) = @_;
  17.         bless \$value, $class;
  18.     }
  19.     
  20.     1;

Note how we load the user pragma myint with an empty list () to prevent its import being called.

The interaction with the Perl compilation happens inside package myint :

  1.     package myint;
  2.     
  3.     use strict;
  4.     use warnings;
  5.     
  6.     sub import {
  7.         $^H{myint} = 1;
  8.     }
  9.     
  10.     sub unimport {
  11.         $^H{myint} = 0;
  12.     }
  13.     
  14.     sub in_effect {
  15.         my $level = shift // 0;
  16.         my $hinthash = (caller($level))[10];
  17.         return $hinthash->{myint};
  18.     }
  19.     
  20.     1;

As pragmata are implemented as modules, like any other module, use myint; becomes

  1.     BEGIN {
  2.         require myint;
  3.         myint->import();
  4.     }

and no myint; is

  1.     BEGIN {
  2.         require myint;
  3.         myint->unimport();
  4.     }

Hence the import and unimport routines are called at compile time for the user's code.

User pragmata store their state by writing to the magical hash %^H , hence these two routines manipulate it. The state information in %^H is stored in the optree, and can be retrieved at runtime with caller(), at index 10 of the list of returned results. In the example pragma, retrieval is encapsulated into the routine in_effect() , which takes as parameter the number of call frames to go up to find the value of the pragma in the user's script. This uses caller() to determine the value of $^H{myint} when each line of the user's script was called, and therefore provide the correct semantics in the subroutine implementing the overloaded addition.

Implementation details

The optree is shared between threads. This means there is a possibility that the optree will outlive the particular thread (and therefore the interpreter instance) that created it, so true Perl scalars cannot be stored in the optree. Instead a compact form is used, which can only store values that are integers (signed and unsigned), strings or undef - references and floating point values are stringified. If you need to store multiple values or complex structures, you should serialise them, for example with pack. The deletion of a hash key from %^H is recorded, and as ever can be distinguished from the existence of a key with value undef with exists.

Don't attempt to store references to data structures as integers which are retrieved via caller and converted back, as this will not be threadsafe. Accesses would be to the structure without locking (which is not safe for Perl's scalars), and either the structure has to leak, or it has to be freed when its creating thread terminates, which may be before the optree referencing it is deleted, if other threads outlive it.

Page index